Initial implementation

Author: tkf

Project.toml

@@ -3,5 +3,9 @@ uuid = "d80eeb9a-aca5-4d75-85e5-170c8b632249"
 authors = ["Takafumi Arakaki <[email protected]> and contributors"]
 version = "0.1.0-DEV"
 
+[deps]
+LLVM = "929cbde3-209d-540e-8aea-75f648917ca0"
+UnsafeAtomics = "013be700-e6cd-48c3-b4a1-df204f14c38f"
+
 [compat]
 julia = "1.6"

src/UnsafeAtomicsLLVM.jl

@@ -2,7 +2,9 @@ baremodule UnsafeAtomicsLLVM
 
 module Internal
 
-using ..UnsafeAtomicsLLVM: UnsafeAtomicsLLVM
+using Core: LLVMPtr
+using LLVM
+using UnsafeAtomics: UnsafeAtomics, Ordering
 
 include("internal.jl")
 

src/internal.jl

@@ -0,0 +1,33 @@
+# TODO: move this to UnsafeAtomics
+julia_ordering_name(::UnsafeAtomics.Internal.LLVMOrdering{name}) where {name} = name
+julia_ordering_name(::typeof(UnsafeAtomics.acquire_release)) = :acquire_release
+julia_ordering_name(::typeof(UnsafeAtomics.sequentially_consistent)) =
+    :sequentially_consistent
+
+@inline UnsafeAtomics.load(ptr::LLVMPtr, order::Ordering) =
+    LLVM.Interop.atomic_pointerref(ptr, Val{julia_ordering_name(order)}())
+
+@inline function UnsafeAtomics.store!(ptr::LLVMPtr, x, order::Ordering)
+    LLVM.Interop.atomic_pointerset(ptr, x, Val{julia_ordering_name(order)}())
+    return
+end
+
+mapop(op::OP) where {OP} = op
+mapop(::typeof(UnsafeAtomics.right)) = LLVM.Interop.right
+
+@inline UnsafeAtomics.modify!(ptr::LLVMPtr, op::OP, x, order::Ordering) where {OP} =
+    LLVM.Interop.atomic_pointermodify(ptr, mapop(op), x, Val{julia_ordering_name(order)}())
+
+@inline UnsafeAtomics.cas!(
+    ptr::LLVMPtr,
+    expected,
+    desired,
+    success_order::Ordering,
+    failure_order::Ordering,
+) = LLVM.Interop.atomic_pointerreplace(
+    ptr,
+    expected,
+    desired,
+    Val{julia_ordering_name(success_order)}(),
+    Val{julia_ordering_name(failure_order)}(),
+)

test/Project.toml

@@ -1,2 +1,6 @@
 [deps]
 Test = "8dfed614-e22c-5e08-85e1-65c5234f0b40"
+TestFunctionRunner = "792026f5-ac9a-4a19-adcb-47b0ce2deb5d"
+
+[compat]
+TestFunctionRunner = "0.1"

test/UnsafeAtomicsLLVMTests/Project.toml

@@ -0,0 +1,12 @@
+name = "UnsafeAtomicsLLVMTests"
+uuid = "f81c5320-9584-4f93-9445-2842f5246c7e"
+authors = ["Takafumi Arakaki <[email protected]> and contributors"]
+version = "0.1.0-DEV"
+
+[deps]
+Test = "8dfed614-e22c-5e08-85e1-65c5234f0b40"
+UnsafeAtomics = "013be700-e6cd-48c3-b4a1-df204f14c38f"
+UnsafeAtomicsLLVM = "d80eeb9a-aca5-4d75-85e5-170c8b632249"
+
+[compat]
+julia = "1.6"

test/UnsafeAtomicsLLVMTests/src/UnsafeAtomicsLLVMTests.jl

@@ -0,0 +1,5 @@
+module UnsafeAtomicsLLVMTests
+
+include("test_core.jl")
+
+end  # module UnsafeAtomicsLLVMTests

test/UnsafeAtomicsLLVMTests/src/test_core.jl

@@ -0,0 +1,72 @@
+module TestCore
+
+import UnsafeAtomicsLLVM
+
+using UnsafeAtomics: UnsafeAtomics, acquire, release, acq_rel
+using UnsafeAtomics.Internal: OP_RMW_TABLE, inttypes
+using Test
+
+llvmptr(xs::Array, i) = reinterpret(Core.LLVMPtr{eltype(xs),0}, pointer(xs, i))
+
+function test_default_ordering()
+    @testset for T in inttypes
+        check_default_ordering(T)
+    end
+end
+
+function check_default_ordering(T::Type)
+    xs = T[rand(T), rand(T)]
+    x1 = rand(T)
+    x2 = rand(T)
+    @debug "xs=$(repr(xs)) x1=$(repr(x1)) x2=$(repr(x2))"
+
+    ptr = llvmptr(xs, 1)
+    GC.@preserve xs begin
+        @test UnsafeAtomics.load(ptr) === xs[1]
+        UnsafeAtomics.store!(ptr, x1)
+        @test xs[1] === x1
+        desired = (old = x1, success = true)
+        @test UnsafeAtomics.cas!(ptr, x1, x2) === (old = x1, success = true)
+        @test xs[1] === x2
+        @testset for (op, name) in OP_RMW_TABLE
+            xs[1] = x1
+            @test UnsafeAtomics.modify!(ptr, op, x2) === (x1 => op(x1, x2))
+            @test xs[1] === op(x1, x2)
+
+            rmw = getfield(UnsafeAtomics, Symbol(name, :!))
+            xs[1] = x1
+            @test rmw(ptr, x2) === x1
+            @test xs[1] === op(x1, x2)
+        end
+    end
+end
+
+function test_explicit_ordering(T::Type = UInt)
+    xs = T[rand(T), rand(T)]
+    x1 = rand(T)
+    x2 = rand(T)
+    @debug "xs=$(repr(xs)) x1=$(repr(x1)) x2=$(repr(x2))"
+
+    ptr = llvmptr(xs, 1)
+    GC.@preserve xs begin
+
+        @test UnsafeAtomics.load(ptr, acquire) === xs[1]
+        UnsafeAtomics.store!(ptr, x1, release)
+        @test xs[1] === x1
+        desired = (old = x1, success = true)
+        @test UnsafeAtomics.cas!(ptr, x1, x2, acq_rel, acquire) === desired
+        @test xs[1] === x2
+        @testset for (op, name) in OP_RMW_TABLE
+            xs[1] = x1
+            @test UnsafeAtomics.modify!(ptr, op, x2, acq_rel) === (x1 => op(x1, x2))
+            @test xs[1] === op(x1, x2)
+
+            rmw = getfield(UnsafeAtomics, Symbol(name, :!))
+            xs[1] = x1
+            @test rmw(ptr, x2, acquire) === x1
+            @test xs[1] === op(x1, x2)
+        end
+    end
+end
+
+end  # module

test/runtests.jl

@@ -1,6 +1,2 @@
-using UnsafeAtomicsLLVM
-using Test
-
-@testset "UnsafeAtomicsLLVM.jl" begin
-    # Write your tests here.
-end
+using TestFunctionRunner
+TestFunctionRunner.@run