Novice Question PEG's

[gsilvers]

Hey not sure if this is the best place for this. If there's an informal irc or something similar shout. I'm just trying out Janet after doing some reading. PEG's are awesome and I'm attempting to build some utility scripts for myself using it.

So I've been able to make a simple file name peg to look for some dated emacs org files:

(def directory "some/path/here/")
(def files (os/dir directory))

(def file-filter-peg
  '{
    :file-month (sequence "2023" "11")
    :file-extension (sequence ".org")
    :main (sequence :file-month :d :d :file-extension)
    }
  )

(each file files
  (if (peg/match file-filter-peg file)
    (do (print directory file " == moved to ==> ")
    )))

Life is great and this works as expected. When I try to replace the hard coded values with a variable things fall apart for example this would error although I would expect it to be equivalent:

(def directory "some/path/here/")
(def files (os/dir directory))
(def current-year "2023")

(def file-filter-peg
  '{
    :file-month (sequence current-year "11")
    :file-extension (sequence ".org")
    :main (sequence :file-month :d :d :file-extension)
    }
  )

(each file files
  (if (peg/match file-filter-peg file)
    (do (print directory file " == moved to ==> ")
    )))

results in an error:

error: grammar error in current-year, unexpected peg source. Can you not use a bound variable within a PEG definition? Is there some trick to doing so? How for example could you use a value from user input or an arg in a PEG otherwise?

Any help would be appreciated I'm sure I'm just missing something syntactically in this language.

[sogaiu]

Possibly using quasiquoting (~) and unquoting (,) might help:

(def file-filter-peg
  ~{
    :file-month (sequence ,current-year "11")
    :file-extension (sequence ".org")
    :main (sequence :file-month :d :d :file-extension)
    }
  )

For other options regarding communication, there are a few mentioned here (Zulip and Gitter / Matrix - I think Zulip is where things might be transitioning to).

[gsilvers]

So this is working. I want to make sure I understand why if you get a chance please let me know if my understanding is right.

The quasi quoting is causing the entire struct to be quoted except for the unquoted value current-year which is instead eval'd first to be the value previously associated with it?

[sogaiu]

I'm not sure I understand the given explanation (^^;

The following might give some idea of what happens though...hopefully there aren't too many errors.

The source text for the quasiquoted struct is processed by the equivalent of parse:

(parse 
  ``
  ~{
    :file-month (sequence ,current-year "11")
    :file-extension (sequence ".org")
    :main (sequence :file-month :d :d :file-extension)
    }
  ``)

to produce (a tuple of 2 elements where the second element is a struct) what might be expressed as:

(quasiquote {:file-extension (sequence ".org") 
             :file-month (sequence (unquote current-year) "11") 
             :main (sequence :file-month :d :d :file-extension)})

When the tuple represented by the (quasiquote ...) above is further processed, the struct is recursively traversed checking for appropriately occurring (unquote ...) tuples (these show up because , + something got transformed into (unquote ...) during parsing) in the process and handling them (e.g. (unquote current-year)) when encountered.

I think this is the sort of process that ultimately yields the desired struct.

Having said all of that, for the simple use of quasiquote and unquote (like the example above), I think it's pretty useful to just imagine it being like templating, where , signals interpolation / fill-me-in. That's what I almost always do in the context of Janet's PEGs anyway :)

[gsilvers]

Sorry it's late here my typing was less than clear. That's 100% what I meant in my statement was the simple case that it triggered it to interpolate the value if the bound variable. Playing with parse and the function individually also makes it super clear.

Thank you for the help and I'll also look to use that other board as well. The small size of Janet is awesome so I'm working on just rewriting some small admin scripts I kept in python to Janet.