How can a binding be a constant when symbol can be redefined?

[joeljuca]

Hello!

I'm reading Janet's docs today to get myself familiar with the language and I stumbled upon this paragraph in the Special section:

(def name meta... value)

This special form binds a value to a symbol. The symbol can be substituted for the value in subsequent expressions for the same result. A binding made by def is a constant and cannot be updated. A symbol can be redefined to a new value, but previous uses of the binding will refer to the previous value of the binding.

Special Forms. https://janet-lang.org/docs/specials.html

It got me confused. How can a def binding be a constant if the symbol itself can be redefined? I'm new to Janet (and LISPs in general), so I might be missing something LISPs do that C-family langs don't, but I couldn't understand these conflicting statements about symbol bindings.

[subsetpark]

In the simplest terms: variables bound with var can be set, and those bound with def cannot. Here's a REPL session:

Janet 1.32.1-a93517f linux/x64/gcc - '(doc)' for help
repl:1:> (def const 10)
10
repl:2:> (defn f [] (print const))
<function f>
repl:4:> (f)
10
nil
repl:5:> (def const 11)
11
repl:6:> (f)
10
nil
repl:8:> (var not-const 10)
10
repl:9:> (defn g [] (print not-const))
<function g>
repl:10:> (g)
10
nil
repl:11:> (set not-const 11)
11
repl:12:> (g)
11
nil

You see that when we define our functions f and g, we close over the variables const and not-const. This means that when we rebind the symbol const, as in repl:5, the closed-over variable inside of f is unchanged; (f) prints out the same, older value.

Meanwhile, because not-const was bound with var, we can update the value to which the symbol is bound with set, as in repl:11. As such, when we call g again: the original value over which it closed has been updated, so the same function now prints something different.

[joeljuca]

Thank you for the explanation and examples, Zach!