Using jaylib, how can I implement game pause?

[uvtc]

How can I pause my jaylib program?

For example, here's my basic "bouncing square" program: https://gist.github.com/uvtc/ad745eb69ed16567d8099f606edd4e7f

I'd like to be able to hit the spacebar to toggle pausing it.

Modifying my original program, here's my attempt at implementing pause:

#!/usr/bin/env janet

(import jaylib :as jl)

(def screen-width  600)
(def screen-height 300)
(def pl-sz 20)

# Start the player (the square) in the middle of the screen,
# with some known initial velocity.
(def pl @{:x (/ screen-width 2)
          :y (/ screen-height 2)
          :vx 2
          :vy 4})

(defn init-game
  []
  (jl/init-window screen-width
                  screen-height
                  "Bouncing Square")
  (jl/set-target-fps 60)
  (jl/hide-cursor))

(defn update-game
  []
  # First, move the square further whichever
  # way it's already going.
  (+= (pl :x) (pl :vx))
  (+= (pl :y) (pl :vy))
  # If it has hit a wall, reverse its
  # direction away from that wall.
  (cond
    (> (pl :x) (- screen-width pl-sz))
    (do (put pl :x (- screen-width pl-sz))
        (put pl :vx (- (pl :vx))))
    (< (pl :x) 0)
    (do (put pl :x 0)
        (put pl :vx (- (pl :vx))))
    (> (pl :y) (- screen-height pl-sz))
    (do (put pl :y (- screen-height pl-sz))
        (put pl :vy (- (pl :vy))))
    (< (pl :y) 0)
    (do (put pl :y 0)
        (put pl :vy (- (pl :vy))))))

(defn draw-game
  []
  (jl/draw-fps 10 10)
  (jl/draw-text (string "x: " (pl :x))
                10 30 16 :blue)
  (jl/draw-text (string "y: " (pl :y))
                10 50 16 :green)
  (jl/draw-text (string "v_x: " (pl :vx))
                10 70 16 :blue)
  (jl/draw-text (string "v_y: " (pl :vy))
                10 90 16 :green)
  # Draw the player.
  (jl/draw-rectangle (pl :x) (pl :y) pl-sz pl-sz :red))

(defn main
  [& args]
  (init-game)
  # For pausing the game:
  (var keep-going true)
  (var i 0) # Just for debugging.
  (while (not (jl/window-should-close))
    
    (if (jl/key-pressed? :space)
      (do
        (++ i)
        (print i)
        (if (true? keep-going)
          (set keep-going false)
          (set keep-going true))
        (print keep-going)))

    (if keep-going
      (do
        (jl/begin-drawing)
        (jl/clear-background [0 0 0])
        (update-game)
        (draw-game)
        (jl/end-drawing))))
  (jl/close-window))

The output to the terminal suggests that every time I hit the spacebar it acts as if I'd hit it twice; for example, after one tap of the spacebar, it yields:

1
false
2
true

Why would it fire twice? (I don't think key-pressed? is supposed to register key-up.)

If I instead start off keep-going as false, the program is frozen and needs to be manually stopped.

This is using Janet 1.15.3.

[uvtc]

Ah. Ok. It works if I surround only the update-game call with the (if keep-going ...).

Not sure why, previously, it hit the key-pressed? twice... maybe something to do with how the game loop works.