docker-cli: add docker contexts support

Adds docker-cli.contexts support. This allows declarative configuration
of [docker
contexts](https://docs.docker.com/engine/manage-resources/contexts/).

Author: will-lol

modules/programs/docker-cli.nix

@@ -32,6 +32,39 @@ in
       '';
     };
 
+    contexts = mkOption {
+      type = lib.types.listOf (
+        lib.types.submodule {
+          freeformType = jsonFormat.type;
+          options.Name = lib.mkOption {
+            type = lib.types.str;
+            description = "The name of the Docker context";
+          };
+        }
+      );
+      default = [ ];
+      example = lib.literalExpression ''
+        [
+          {
+            Name = "example";
+            Metadata = {
+              Description = "example1";
+
+            };
+            Endpoints = {
+              docker = {
+                Host = "unix://example2";
+              };
+            };
+          }
+        ];
+      '';
+      description = ''
+        Array of docker context configurations. See:
+        <https://docs.docker.com/engine/manage-resources/contexts/
+      '';
+    };
+
     settings = mkOption {
       type = jsonFormat.type;
       default = { };
@@ -62,7 +95,15 @@ in
         "${cfg.configDir}/config.json" = {
           source = jsonFormat.generate "config.json" cfg.settings;
         };
-      };
+      }
+      // builtins.listToAttrs (
+        map (s: {
+          name = "${cfg.configDir}/contexts/meta/${builtins.hashString "sha256" s.Name}/meta.json";
+          value = {
+            source = jsonFormat.generate "config.json" s;
+          };
+        }) cfg.contexts
+      );
     };
   };
 }

tests/modules/programs/docker-cli/default.nix

@@ -1,4 +1,5 @@
 {
   docker-cli = ./example-config.nix;
   docker-cli-empty-config = ./empty-config.nix;
+  docker-cli-contexts = ./example-contexts.nix;
 }

tests/modules/programs/docker-cli/example-contexts.json

@@ -0,0 +1,11 @@
+{
+  "Endpoints": {
+    "docker": {
+      "Host": "unix://example2"
+    }
+  },
+  "Metadata": {
+    "Description": "example1"
+  },
+  "Name": "example"
+}

tests/modules/programs/docker-cli/example-contexts.nix

@@ -0,0 +1,38 @@
+{
+  config,
+  ...
+}:
+{
+  programs.docker-cli = {
+    enable = true;
+
+    configDir = ".docker2";
+
+    contexts = [
+      {
+        Name = "example";
+        Metadata = {
+          Description = "example1";
+
+        };
+        Endpoints = {
+          docker = {
+            Host = "unix://example2";
+          };
+        };
+      }
+    ];
+  };
+
+  nmt.script =
+    let
+      cfgDocker = config.programs.docker-cli;
+      configTestPath = "home-files/${cfgDocker.configDir}/contexts/meta/50d858e0985ecc7f60418aaf0cc5ab587f42c2570a884095a9e8ccacd0f6545c/meta.json";
+    in
+    ''
+      assertPathNotExists home-files/.docker/config.json
+      assertFileExists ${configTestPath}
+      assertFileContent ${configTestPath} \
+        ${./example-contexts.json}
+    '';
+}