lib/helpers: refactor mkPlugin helpers

Author: GaetanLepage

lib/helpers.nix

@@ -10,23 +10,23 @@ let
   nixvimUtils = import ./utils.nix { inherit lib nixvimTypes _nixvimTests; };
   nixvimOptions = import ./options.nix { inherit lib nixvimTypes nixvimUtils; };
   inherit (import ./to-lua.nix { inherit lib; }) toLuaObject;
-in
-{
-  maintainers = import ./maintainers.nix;
-  keymaps = import ./keymap-helpers.nix { inherit lib nixvimOptions nixvimTypes; };
-  autocmd = import ./autocmd-helpers.nix { inherit lib nixvimOptions nixvimTypes; };
-  neovim-plugin = import ./neovim-plugin.nix {
+  nixvimPlugins = import ./plugin {
     inherit
       lib
       nixvimOptions
       nixvimUtils
       toLuaObject
       ;
   };
-  vim-plugin = import ./vim-plugin.nix { inherit lib nixvimOptions nixvimUtils; };
+in
+{
+  maintainers = import ./maintainers.nix;
+  keymaps = import ./keymap-helpers.nix { inherit lib nixvimOptions nixvimTypes; };
+  autocmd = import ./autocmd-helpers.nix { inherit lib nixvimOptions nixvimTypes; };
   inherit nixvimTypes;
   inherit toLuaObject;
 }
 // nixvimUtils
 // nixvimOptions
 // nixvimBuilders
+// nixvimPlugins

lib/neovim-plugin.nix

@@ -0,0 +1,29 @@
+{
+  lib,
+  nixvimOptions,
+  nixvimUtils,
+  toLuaObject,
+  ...
+}:
+rec {
+  mkPlugin = import ./mk-plugin.nix { inherit lib nixvimOptions nixvimUtils; };
+
+  neovim-plugin = import ./neovim-plugin.nix {
+    inherit
+      lib
+      nixvimOptions
+      nixvimUtils
+      toLuaObject
+      mkPlugin
+      ;
+  };
+
+  vim-plugin = import ./vim-plugin.nix {
+    inherit
+      lib
+      nixvimOptions
+      nixvimUtils
+      mkPlugin
+      ;
+  };
+}

lib/plugin/default.nix

@@ -0,0 +1,90 @@
+{
+  lib,
+  nixvimOptions,
+  nixvimUtils,
+}:
+with lib;
+config:
+{
+  name,
+  maintainers,
+  url ? defaultPackage.meta.homepage,
+  imports ? [ ],
+  description ? null,
+  # deprecations
+  optionsRenamedToSettings ? [ ],
+  # colorscheme
+  isColorscheme ? false,
+  colorscheme ? name,
+  # options
+  originalName ? name,
+  defaultPackage ? null,
+  extraOptions ? { },
+  # config
+  extraConfig ? cfg: { },
+  extraPlugins ? [ ],
+  extraPackages ? [ ],
+}:
+let
+  namespace = if isColorscheme then "colorschemes" else "plugins";
+
+  optionsRenamedToSettingsWarnings =
+    let
+      basePluginPath = [
+        namespace
+        name
+      ];
+      settingsPath = basePluginPath ++ [ "settings" ];
+    in
+    map (
+      option:
+      let
+        optionPath = if isString option then [ option ] else option; # option is already a path (i.e. a list)
+
+        optionPathSnakeCase = map nixvimUtils.toSnakeCase optionPath;
+      in
+      mkRenamedOptionModule (
+        [
+          namespace
+          name
+        ]
+        ++ optionPath
+      ) (settingsPath ++ optionPathSnakeCase)
+    ) optionsRenamedToSettings;
+in
+{
+  meta = {
+    inherit maintainers;
+    nixvimInfo = {
+      inherit description url;
+      path = [
+        namespace
+        name
+      ];
+    };
+  };
+
+  imports = optionsRenamedToSettingsWarnings ++ imports;
+
+  options.${namespace}.${name} =
+    {
+      enable = mkEnableOption originalName;
+    }
+    // (optionalAttrs (defaultPackage != null) {
+      package = nixvimOptions.mkPluginPackageOption originalName defaultPackage;
+    })
+    // extraOptions;
+
+  config =
+    let
+      cfg = config.${namespace}.${name};
+    in
+    mkIf cfg.enable (mkMerge [
+      {
+        extraPlugins = extraPlugins ++ optional (defaultPackage != null) cfg.package;
+        inherit extraPackages;
+      }
+      (extraConfig cfg)
+      (optionalAttrs (isColorscheme && (colorscheme != null)) { colorscheme = mkDefault colorscheme; })
+    ]);
+}

lib/plugin/mk-plugin.nix

@@ -0,0 +1,102 @@
+{
+  lib,
+  nixvimOptions,
+  toLuaObject,
+  nixvimUtils,
+  mkPlugin,
+}:
+with lib;
+rec {
+  mkSettingsOption =
+    {
+      pluginName ? null,
+      options ? { },
+      description ?
+        if pluginName != null then
+          "Options provided to the `require('${pluginName}').setup` function."
+        else
+          throw "mkSettingsOption: Please provide either a `pluginName` or `description`.",
+      example ? null,
+    }:
+    nixvimOptions.mkSettingsOption { inherit options description example; };
+
+  # TODO: DEPRECATED: use the `settings` option instead
+  extraOptionsOptions = {
+    extraOptions = mkOption {
+      default = { };
+      type = with types; attrsOf anything;
+      description = ''
+        These attributes will be added to the table parameter for the setup function.
+        Typically, it can override NixVim's default settings.
+      '';
+    };
+  };
+
+  mkNeovimPlugin =
+    config:
+    {
+      name,
+      defaultPackage, # make this parameter mandatory for neovim plugins
+      # deprecations
+      deprecateExtraOptions ? false,
+      # colorscheme
+      isColorscheme ? false,
+      # options
+      settingsOptions ? { },
+      settingsExample ? null,
+      # config
+      luaName ? name,
+      callSetup ? true,
+      ...
+    }@args:
+    mkPlugin config (
+      (removeAttrs args [
+        "callSetup"
+        "deprecateExtraOptions"
+        "extraConfig"
+        "extraOptions"
+        "imports"
+        "luaName"
+        "settingsExample"
+        "settingsOptions"
+      ])
+      // {
+        imports =
+          let
+            basePluginPath = [
+              (if isColorscheme then "colorschemes" else "plugins")
+              name
+            ];
+            settingsPath = basePluginPath ++ [ "settings" ];
+          in
+          (args.imports or [ ])
+          ++ (optional deprecateExtraOptions (
+            mkRenamedOptionModule (basePluginPath ++ [ "extraOptions" ]) settingsPath
+          ));
+
+        extraOptions = {
+          settings = mkSettingsOption {
+            pluginName = name;
+            options = settingsOptions;
+            example = settingsExample;
+          };
+        } // (args.extraOptions or { });
+
+        extraConfig =
+          let
+            extraConfigNamespace = if isColorscheme then "extraConfigLuaPre" else "extraConfigLua";
+          in
+          cfg:
+          mkMerge (
+            [
+              {
+                ${extraConfigNamespace} = optionalString callSetup ''
+                  require('${luaName}').setup(${toLuaObject cfg.settings})
+                '';
+              }
+            ]
+            ++ (optional (args ? extraConfig) (args.extraConfig cfg))
+          );
+      }
+    );
+}