Support systemd on the debian family

Most systemd systems allow using a sysconfig style environments file,
but not debian. If we do not want to adjust daemon options, we need to use
an systemd drop-in service file.

Author: vStone

.fixtures.yml

@@ -1,3 +1,4 @@
 fixtures:
   repositories:
     stdlib: 'https://github.com/puppetlabs/puppetlabs-stdlib.git'
+    systemd: 'https://github.com/camptocamp/puppet-systemd.git'

manifests/init.pp

@@ -355,8 +355,10 @@
   $trap_service_hasrestart      = $snmp::params::trap_service_hasrestart,
   String[1] $template_snmpd_conf          = $snmp::params::template_snmpd_conf,
   String[1] $template_snmpd_sysconfig     = $snmp::params::template_snmpd_sysconfig,
+  String[1] $template_snmpd_systemd_override = $snmp::params::template_snmpd_systemd_override,
   String[1] $template_snmptrapd           = $snmp::params::template_snmptrapd,
   String[1] $template_snmptrapd_sysconfig = $snmp::params::template_snmptrapd_sysconfig,
+  String[1] $template_snmptrapd_systemd_override   = $snmp::params::template_snmptrapd_systemd_override,
   Boolean $openmanage_enable    = $snmp::params::openmanage_enable,
   Boolean $master               = $snmp::params::master,
   $agentx_perms                 = $snmp::params::agentx_perms,
@@ -439,6 +441,43 @@
     }
   }
 
+  if $facts['os']['family'] == 'Debian' and $facts['service_provider'] == 'systemd' {
+    include 'systemd::systemctl::daemon_reload'
+    file {[
+        '/etc/systemd/system/snmpd.service.d',
+        '/etc/systemd/system/snmptrapd.service.d/',
+      ]:
+      ensure => 'directory',
+      owner  => 'root',
+      group  => 'root',
+      mode   => '0755',
+    }
+    file {'/etc/systemd/system/snmpd.service.d/local.conf':
+      ensure  => 'file',
+      owner   => 'root',
+      group   => 'root',
+      mode    => '0644',
+      content => template($template_snmpd_systemd_override),
+      require => Package['snmpd'],
+      notify  => [
+        Exec['systemctl-daemon-reload'],
+        Service['snmpd'],
+      ],
+    }
+    file {'/etc/systemd/system/snmptrapd.service.d/local.conf':
+      ensure  => 'file',
+      owner   => 'root',
+      group   => 'root',
+      mode    => '0644',
+      content => template($template_snmptrapd_systemd_override),
+      require => Package['snmptrapd'],
+      notify  => [
+        Exec['systemctl-daemon-reload'],
+        Service['snmptrapd'],
+      ],
+    }
+  }
+
   # Config
   file { 'snmpd.conf':
     ensure  => $file_ensure,
@@ -501,14 +540,22 @@
     }
   }
 
+  # If options change on debian with systemd, we need to reload the systemd daemon
+  # before restarting the service.
+  if $facts['os']['family'] == 'Debian' and $facts['service_provider'] == 'systemd' {
+    $service_requires = [File['var-net-snmp'], Exec['systemctl-daemon-reload']]
+  } else {
+    $service_requires = File['var-net-snmp']
+  }
+
   # Services
   service { 'snmptrapd':
     ensure     => $trap_service_ensure_real,
     name       => $trap_service_name,
     enable     => $trap_service_enable_real,
     hasstatus  => $trap_service_hasstatus,
     hasrestart => $trap_service_hasrestart,
-    require    => File['var-net-snmp'],
+    require    => $service_requires,
     subscribe  => File['snmptrapd.conf'],
   }
 
@@ -518,7 +565,7 @@
     enable     => $service_enable_real,
     hasstatus  => $service_hasstatus,
     hasrestart => $service_hasrestart,
-    require    => File['var-net-snmp'],
+    require    => $service_requires,
     subscribe  => File['snmpd.conf'],
   }
 

manifests/params.pp

@@ -75,8 +75,10 @@
   $snmpv2_enable = true
   $template_snmpd_conf = 'snmp/snmpd.conf.erb'
   $template_snmpd_sysconfig = "snmp/snmpd.sysconfig-${facts['os']['family']}.erb"
+  $template_snmpd_systemd_override   = 'snmp/snmpd.systemd_override.erb'
   $template_snmptrapd = 'snmp/snmptrapd.conf.erb'
   $template_snmptrapd_sysconfig = "snmp/snmptrapd.sysconfig-${facts['os']['family']}.erb"
+  $template_snmptrapd_systemd_override = 'snmp/snmptrapd.systemd_override.erb'
 
   $majordistrelease = $facts['os']['release']['major']
 
@@ -146,8 +148,13 @@
         $varnetsnmp_group       = 'snmp'
       }
 
-      $sysconfig      = '/etc/default/snmpd'
-      $trap_sysconfig = '/etc/default/snmptrapd'
+      if $::facts['service_provider'] == 'systemd' {
+        $sysconfig      = undef
+        $trap_sysconfig = undef
+      } else {
+        $sysconfig      = '/etc/default/snmpd'
+        $trap_sysconfig = '/etc/default/snmptrapd'
+      }
 
       $package_name             = 'snmpd'
       $snmptrapd_package_name   = 'snmptrapd'

metadata.json

@@ -9,6 +9,10 @@
   "source": "https://github.com/voxpupuli/puppet-snmp.git",
   "tags": [ "snmp", "net-snmp", "monitoring" ],
   "dependencies": [
+    {
+      "name": "camptocamp/systemd",
+      "version_requirement": ">= 1.0.0 < 3.0.0"
+    },
     {
       "name": "puppetlabs/stdlib",
       "version_requirement": ">= 4.13.1 < 6.0.0"

templates/snmpd.systemd_override.erb

@@ -0,0 +1,10 @@
+[Service]
+ExecStart=
+ExecStart=/usr/sbin/snmpd <%= @snmpd_options %>
+<% if @snmpd_options.split(' ').include?('-f') -%>
+Type=
+Type=simple
+<% else -%>
+Type=
+Type=forking
+<% end -%>

templates/snmptrapd.systemd_override.erb

@@ -0,0 +1,10 @@
+[Service]
+ExecStart=
+ExecStart=/usr/sbin/snmptrapd <%= @snmptrapd_options %>
+<% if @snmptrapd_options.split(' ').include?('-f') -%>
+Type=
+Type=simple
+<% else -%>
+Type=
+Type=forking
+<% end -%>