Merge pull request #6 from xenit-eu/ACC-1443

[ACC-1443] Prepare for publication to maven central

Author: thijslemmens

build.gradle

@@ -5,10 +5,14 @@ plugins {
     id 'org.sonarqube'
 }
 
+apply from: "${rootDir}/gradle/publish.gradle"
+
 java {
     toolchain {
         languageVersion = JavaLanguageVersion.of(17)
     }
+    withSourcesJar()
+    withJavadocJar()
 }
 
 jacocoTestReport {

gradle.properties

@@ -0,0 +1,2 @@
+group=com.contentgrid.hal.client
+description=HAL and HAL-FORMS client

gradle/publish.gradle

@@ -0,0 +1,73 @@
+apply plugin: 'maven-publish'
+apply plugin: 'signing'
+
+publishing {
+    publications {
+
+        all {
+            pom {
+                url = 'https://github.com/xenit-eu/java-hal-client'
+                name = project.name
+                description = project.description
+
+                scm {
+                    connection = 'scm:git:[email protected]:xenit-eu/java-hal-client.git'
+                    developerConnection = 'scm:git:[email protected]:xenit-eu/java-hal-client.git'
+                    url = 'https://github.com/xenit-eu/java-hal-client.git'
+                }
+
+                developers {
+                    developer {
+                        name = "XeniT"
+                        organization = "XeniT Solutions NV"
+                    }
+                }
+
+                licenses {
+                    license {
+                        name = 'The Apache License, Version 2.0'
+                        url = 'https://www.apache.org/licenses/LICENSE-2.0'
+                    }
+                }
+            }
+        }
+
+        library(MavenPublication) {
+            from components.java
+
+            versionMapping {
+                usage("java-api") {
+                    fromResolutionResult()
+                }
+                usage("java-runtime") {
+                    fromResolutionResult()
+                }
+            }
+        }
+    }
+
+    repositories {
+        if ("${project.version}".endsWith('-SNAPSHOT')) {
+            sonatypeSnapshots {
+                url = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
+                credentials {
+                    username = project.findProperty('sonatype_username')
+                    password = project.findProperty('sonatype_password')
+                }
+            }
+        } else {
+            sonatypeMavenCentral {
+                url = "https://s01.oss.sonatype.org/service/local/"
+                credentials {
+                    username = project.findProperty('sonatype_username')
+                    password = project.findProperty('sonatype_password')
+                }
+            }
+        }
+    }
+
+}
+
+tasks.named('check').configure {
+    dependsOn('checkMavenCentralRequirements')
+}

settings.gradle

@@ -23,4 +23,4 @@ reckon {
     stageCalc = { inventory, targetNormal -> java.util.Optional.empty() }
 }
 
-rootProject.name = 'java-hal-client'
+rootProject.name = 'hal-client'